MODEL A1Betail

LET 

imax  = 2   ! Nombre d'aliments
jmax = 3   ! Nombre de Matieres Premieres

TABLES

P(jmax,3)  ! Pourcentages de proteines, lipides et fibres de chaque MP
QMax(jmax) ! Quantites maximales disponibles de chaque matiere premiere
Pr(jmax)   ! Prix d'achat des matieres premieres    

            

DATA
Pr   = 0.8, 1, 0.75   
QMax = 11900, 23500, 750            
P(1,1) =   13.6, 7.1,   7
P(2,1) =   4.1, 2.4, 3.7
P(3,1) =   5, 0.3,  25



VARIABLES

Q(imax)     ! Quantites de chaque aliment produit
X(imax,jmax)  ! Quantité de chaque matiere premiere utilisee dans chaque aliment 
CoutAchat
CoutBroy
CoutMelange            
CoutGranul
CoutTamis

CONSTRAINTS

! Cout de revient a minimiser
Cout : CoutAchat + &        ! Cout d'achat des MP
       CoutBroy + &         ! Cout de broyage
       CoutMelange + &      ! Cout de melange
       CoutGranul + &       ! Cout de granulation
       CoutTamis$           ! Cout de tamisage

achat         : CoutAchat   = Sum(i=1:imax,j=1:jmax)   Pr(j)*X(i,j)
broyage       : CoutBroy    = Sum(i=1:imax,j=1:jmax-1) 1.5*X(i,j)   
melange       : CoutMelange = Sum(i=1:imax,j=1:jmax)   0.3*X(i,j)
granulation   : CoutGranul  = 2.5*Q(1)  
Tamisage      : CoutTamis   = 1*Q(2)

QteProduites(i=1:imax)    : Q(i) = Sum(j=1:jmax) X(i,j)
AuMoins1(i=1:imax)        : Sum(j=1:jmax)P(j,1)*X(i,j)>9.5*Q(i)
AuMoins2(i=1:imax)        : Sum(j=1:jmax)P(j,2)*X(i,j)>2  *Q(i)
AuPlus(i=1:imax)          : Sum(j=1:jmax)P(j,3)*X(i,j)<6  *Q(i)

QteMax(j=1:jmax)         : Sum(i=1:imax)X(i,j)<QMax(j)

Demande1         : Q(1)>9000
Demande2         : Q(2)>12000

END